home *** CD-ROM | disk | FTP | other *** search
/ Magnum One / Magnum One (Mid-American Digital) (Disc Manufacturing).iso / d3 / allmac21.arc / MACRO24.ARC / MACRO24.QM < prev    next >
Text File  |  1990-08-27  |  25KB  |  486 lines
  1. *                           (MacroMaker)  v2.4
  2. * ┌────────────────────────[ Index of Macros ]──   ────────────────────────────┐
  3. * │(Ctl_1) - Finds first word on cursor line "marked" with () in document below│
  4. * │(Alt_1) - Loads txtfile from list of available txtfiles sorted by name      │
  5. * │(Alt_2) - Refresh with "standard" macfile                                   │
  6. * │(Alt_3) - Merges current macros with designated txtfile, reads macfile      │
  7. * │(Alt_4) - Appends txtfile to "standard" txtfile & macfile, reads macfile    │
  8. * │(Alt_5) - Gets error file                                                   │
  9. * │(Alt_6) - Makes dummy txtfile from current txtfile                          │
  10. * │(Alt_7) - Makes & reads dummy macfile from txtfile                          │
  11. * │(Alt_8) - Reads macfile of txtfile                                          │
  12. * │(Alt_9) - Makes macfile only                                                │
  13. * │(Alt_0) - Makes & reads macfile                                             │
  14. * │(Alt_t) - Reads macfiles from list by date                                  │
  15. * │(Alt_n) - Reads macfiles from list by name                                  │
  16. * │                                                                            │
  17. * │(Description)    - MacroMaker Macros                                        │
  18. * │(Requirements)   - and use                                                  │
  19. * │(Startup)        - See MACRO.DOC for startup instructions                   │
  20. * │(Macros)         - MacroMaker Macros                                        │
  21. * │(Other) Macros   - not included                                             │
  22. * │(Version) history                                                           │
  23. * └────────[ be sure to leave at least one blank line at end of Index ]────────┘
  24.  
  25.  
  26.  
  27. * (Description):
  28. *
  29. *        (MacroMaker) MACRO24.ZIP Contains QEdit macros to easily convert
  30. *        macros to & from text/binary (txtfile/macfile):
  31. *
  32. *        @1 - Loads txtfile from list of available txtfiles sorted by name
  33. *        @2 - Refresh with "standard" macfile
  34. *        @3 - Merges current macros with designated txtfile, reads macfile
  35. *        @4 - Appends txtfile to "standard" txtfile & macfile, reads macfile
  36. *        @5 - Gets error file
  37. *        @6 - Makes dummy txtfile from current txtfile
  38. *        @7 - Makes & reads dummy macfile from txtfile
  39. *        @8 - Reads macfile of txtfile
  40. *        @9 - Makes macfile only
  41. *        @0 - Makes & reads macfile
  42. *        @t - Reads macfiles from list by date
  43. *        @n - Reads macfiles from list by name
  44. *        ^1- Finds first word on cursor line "marked" with () in document below
  45. *
  46. *        Primary file names in FILE11.ZIP have been changed from SORTxx.xxx
  47. *        in SORT10.ZIP. Alt_f1-f3 in MACRO24.ZIP are nearly identical to
  48. *        Alt_1-3 in FILE11.ZIP except Alt_1-3 macros in SORT10.ZIP require
  49. *        the use of Norton's DS and Buerg's SORTF. Macros in FILE11.ZIP
  50. *        use Directory Extender DX included in FILE11.ZIP. The latest
  51. *        version now is FILE12.ZIP.
  52. *
  53. *
  54. *
  55. *
  56. * (Requirements) and Use (see MACRO.DOC for (startup) instructions):
  57. *
  58. *         1. Txtfile name extension must be [file].QM, Macfile [file].MAC.
  59. *         2. Change G:\QE (location of QMAC) and optional ram disk J:\ (also
  60. *            in batch files) for your setup. Ram disk is optional but faster
  61. *            than a hard drive. Use any active drive letter to replace J:\.
  62. *         3. Batch files must be in path or current directory. INSERT must
  63. *            be ON. Run macros and press Enter to continue when paused.
  64. *         4. Modify "g:\qe\MACROS.xxx" in macros to your "standard" macro.
  65. *            Be careful to use or not use extension as shown, with spaces.
  66. *         5. Must have Norton DS to use Alt-1 & N and Buerg's SORTF to
  67. *            use Alt T. (DS & SORTF are not included.)
  68.  
  69. * Macros Included:
  70. *
  71. *         @1-Selects txtfile to load from txtfile list of all available
  72. *            txtfiles in directory sorted by Name.
  73. *         @2-Refreshes macro buffer with "standard" macfile.
  74. *         @3-Merges designated txtfile [file].qm with current macros.
  75. *            QEdit overwrites current macros when reading a new macfile.
  76. *         @4-Appends txtfile [file].qm to "standard" txt and macfile and reads.
  77. *         @5-Refreshes and gets error file j:j in window.
  78. *         @6-Makes dummy txtfile from current macros.
  79. *         @7-Makes and reads dummy macfile from txtfile [file].qm.
  80. *         @8-Reads macfile of txtfile [file].qm.
  81. *         @9-Makes macfile only from txtfile [file].qm. No read.
  82. *         @0-Makes and reads macfile from txtfile [file].qm.
  83. *         @t-Selects macfile to read from macro list of all available
  84. *            macfiles in directory sorted by Date.
  85. *            (Uses Norton DS not included)
  86. *         @n-Selects macfile to read from macro list of all available
  87. *            macfiles in directory sorted by Name.
  88. *            (Uses Vernon Buerg's SORTF not included)
  89.  
  90.  
  91.  
  92. * (Macros):
  93. *
  94. *┌─────────────────────────────────────────────────────────────────┐
  95. *│(Alt_1) Selects txtfile to load from txtfile list sorted by Name │
  96. *└─────────────────────────────────────────────────────────────────┘
  97. *    Does not read macfile of txtfile selected.
  98. *
  99. @1 macrobegin
  100.         dos "sort-N1" return return                          * Sort list/name
  101.         editfile "j:j" return quit editfile "j:j" return     * get file list
  102.         delline delline delline return                       * del dir heading
  103.         "Cursor "#25                                         * instructions
  104.         markblockend begline markblockbegin                  * highlight
  105.         gotoblockend return return                           * space
  106.         pause markword copy                                  * get macfile name
  107.         editfile paste  ".qm" return quit                    * load text macro
  108.         editfile paste  ".qm" return                         * no read macfile
  109. *
  110. * 86 bytes Thu  07-26-1990  02:11:42
  111.  
  112.  
  113.  
  114. *┌───────────────────────────────────────────────────────────┐
  115. *│(Alt_2) Refreshes macro buffer with "standard" macfile     │
  116. *└───────────────────────────────────────────────────────────┘
  117. * Remember to modify "g:\qe\macros.mac" with your "standard" macfile.
  118. *
  119. @2 MacroBegin MacroRead "g:\qe\macros.mac" Return
  120. *
  121. * 38 bytes Thu  07-26-1990  02:16:58
  122.  
  123.  
  124.  
  125. *┌────────────────────────────────────────────────────────────────┐
  126. *│(Alt_3) Merges designated txtfile [file].qm with current macros │
  127. *└────────────────────────────────────────────────────────────────┘
  128. *
  129. @3 macrobegin
  130.    editfile "j:$" return killfile quit                       * gets macro to
  131.    editfile "j:$" return return                              *  be merged with
  132.    "Merge macro ? "return cursorup endline cursorright pause *  
  133.    cursorleft markword cut killfile quit                     *                     *
  134.    macrowrite "dum4.mac" return  return                      * write cur macros
  135.    dos "qmacM " paste return return                          * makes apnd macro
  136.    horizontalwindow                                          *
  137.    editfile "j:j" return quit editfile "j:j" return          * get error file
  138.    insertdate  inserttime                                    * put date in j:j
  139.    find "(" return return jfalse labl1:                      * get error line #
  140.    wordright unmarkblock markblockbegin wordright            *
  141.    cursorleft markblockend copy savefile prevwindow          *
  142.    gotoline paste return makectrofscreen pause zoomwindow    * go to error #1
  143.    jump labl2:                                               *
  144.  labl1:
  145.    prevwindow zoomwindow                                     * no error, go to
  146.    jump labl2:                                               *      prevwindow
  147.  labl2:
  148.    editfile "dum4.qm" return                                 * load apnd. txtfil
  149.    splitline newfile "N" return endfile return               *
  150.   "*...Tom Hogshead " insertdate inserttime                  * stamp bottom
  151.   "Appended " paste endline ".qm to current macros"          *  w/ date/time
  152.    unmarkblock savefile macroread "dum4.mac" return          * read apnd. macfil
  153. *
  154. * 288 bytes Thu  07-26-1990  02:17:16
  155.  
  156.  
  157.  
  158. *┌───────────────────────────────────────────────────────────┐
  159. *│(Alt_4) Appends txtfile [file].qm  to a "standard" txtfile │
  160. *│     named macros.qm and reads appended macfile.           │
  161. *└───────────────────────────────────────────────────────────┘
  162. *  Remember to modify "g:\qe\macros" (no extension) in this
  163. *  macro to your "standard" macfile.
  164. *
  165. @4 macrobegin
  166.    savefile dos "qmacTA2 " currentfilename                   * make file.mac
  167.    backspace backspace backspace " "                         *
  168.   "g:\qe\macros" return   **(no EXTension)**                 *
  169.                 unmarkblock             * unmarkblock
  170.                 insertline              * insert blank line
  171.                 markcolumn              * markcolumn
  172.                 currentfilename         * get currentfilename
  173.                 storescrbuff "1" return * store currentfilename/scrbf 1
  174.                 copy                    * copy filename to scrap
  175.                 delline                 * delline
  176.    editfile "j:j" return quit                                * quit j:j
  177.    editfile paste  return horizontalwindow                   * load file.qm
  178.    editfile "j:j" return                                     * get error file
  179.    insertdate  inserttime                                    * put date in j:j
  180.    find "(" return return jfalse labl1:                      * get error line #
  181.    wordright unmarkblock markblockbegin wordright            *
  182.    cursorleft markblockend copy savefile prevwindow          *
  183.    gotoline paste return makectrofscreen pause zoomwindow    * go to error line
  184.    jump labl2:                                               *
  185.  labl1:                                                      *
  186.    prevwindow zoomwindow                                     * no error, go to
  187.    jump labl2:                                               *      prevwindow labl2:                                                      *
  188.  labl2:
  189.    editfile "j:$" return quit                                *
  190.    editfile "j:$" return killfile                            * load dum3.qm
  191.    editfile "dum3.qm"    return quit
  192.    editfile "dum3.qm"    return                              * load dum3.qm
  193.    begfile cursordown endline                                * stamp
  194.    cursorright
  195.   "from:" cursorright
  196.    getscrbuff "1" return
  197.    unmarkblock endfile return                                * line on bot
  198.   "*" cursorright "Tom Hogshead"
  199.    cursorright cursorright* cursorright
  200.    insertdate inserttime                                     * - name/date bot
  201.   "Appnd:" cursorright
  202.    getscrbuff "1" return unmarkblock                         * - file on bot
  203.    savefile macroread currentfilename                        * read dum3.mac
  204.    backspace backspace "MAC" return                          *
  205. *
  206. * 279 bytes Thu  07-26-1990  02:17:34
  207. * 251 bytes Thu  07-26-1990  09:00:10
  208.  
  209.  
  210.  
  211. *┌──────────────────────────────────────────────────────────────┐
  212. *│(Alt_5) Gets error file (j:j) in window. Press ENTER to remove│
  213. *└──────────────────────────────────────────────────────────────┘
  214. *
  215. @5  macrobegin
  216.     unmarkblock begline return cursorup                      * cut name/scrap
  217.     markblockbegin currentfilename markblockend cut          *
  218.     editfile paste return                                    * restore name
  219.     horizontalwindow                                         * make window
  220.     editfile "j:j" return                                    * load j:j
  221.     makectrofscreen pause zoomwindow                         * zoom on pause
  222.     editfile paste return                                    * restore name
  223. *
  224. * 30 bytes Thu  07-26-1990  09:03:05
  225.  
  226.  
  227.  
  228.  
  229. * ┌────────────────────────────────────────────┐
  230. * │ (Alt_6) Makes textfile from current macros │
  231. * └────────────────────────────────────────────┘
  232. *
  233. @6 macrobegin
  234.    macrowrite "c:$.mac" return return   * write to dum.mac
  235.    dos "qmact c:$" return return        * make dum.qm
  236.    editfile "c:$" return quit           * quit old dum.qm
  237.    editfile return                      * load new dum.qm
  238.    endfile                              *
  239. *
  240. * 54 bytes Thu  08-21-1980  19:54:12
  241.  
  242.  
  243.  
  244.  
  245. *┌───────────────────────────────────────────────────────────┐
  246. *│ (Alt_7) Copies txtfile [file].QM to dummy txtfile.        │
  247. *│  Makes and reads macfile.                                 │
  248. *└───────────────────────────────────────────────────────────┘
  249. *
  250. @7 macrobegin
  251.    savefile unmarkblock writeblock "c:$.qm"                  * copy file.qm
  252.    return return                                             *    to c:$.qm
  253.    unmarkblock begline return cursorup                       * cut name/scrbuf 1
  254.    markcolumn currentfilename                                *
  255.    storescrbuff "1" return delline                           *
  256.    editfile "c:$.qm" return quit editfile return             * load c:$.qm
  257.    dos "qmacbj c:$" return                                   * make file.mac
  258.    unmarkblock begline return cursorup                       * cut name/scrap
  259.    markblockbegin currentfilename markblockend cut           *
  260.    editfile "j:j" return quit                                * quit j:j
  261.    editfile paste return horizontalwindow                    * load file.qm
  262.    editfile "j:j" return                                     * get error file
  263.    insertdate  inserttime                                    * put date in j:j
  264.    find "(" return return jfalse labl1:                      * get error line #
  265.    wordright unmarkblock markblockbegin wordright            *
  266.    cursorleft markblockend copy savefile prevwindow          *
  267.    gotoline paste return makectrofscreen pause zoomwindow    * go to error line
  268.    jump labl2:                                               *
  269.  labl1:                                                      *
  270.    prevwindow zoomwindow                                     * no error, go to
  271.    jump labl2:                                               *   prevwindow
  272.  labl2:                                                      *
  273.    dos "qmact c:$" return return                             * make c:$.qm
  274.    editfile "c:$.qm" return quit editfile return             * load c:$.qm
  275.    endfile return                                            *
  276.    "*" insertdate inserttime                                 * - name/date bot
  277.    getscrbuff "1" return unmarkblock                         * - file on bot
  278.    savefile                                                  *
  279.    macroread currentfilename                                 * read c:$.mac
  280.    backspace backspace "MAC" return                          *
  281. *
  282. * 194 bytes Thu  08-21-1980  19:54:29
  283.  
  284.  
  285.  
  286.  
  287.  
  288. *┌───────────────────────────────────────────────────────────┐
  289. *│(Alt_8) Reads macfile from txtfile [file].QM               │
  290. *└───────────────────────────────────────────────────────────┘
  291. *
  292. @8 macrobegin
  293.    macroread currentfilename backspace backspace "mac" return                          *
  294. *
  295. * 15 bytes Thu  07-26-1990  02:18:38
  296.  
  297.  
  298.  
  299. *┌───────────────────────────────────────────────────────────┐
  300. *│(Alt_9) Makes macfile from txtfile [file].QM, no read      │
  301. *└───────────────────────────────────────────────────────────┘
  302. *
  303. @9 macrobegin savefile dos "qmacb " currentfilename           * make file.mac
  304.    backspace backspace backspace return                       * remove ".qm"
  305. *
  306. * 23 bytes Thu  07-26-1990  02:18:56 9
  307.  
  308.  
  309.  
  310. *┌───────────────────────────────────────────────────────────┐
  311. *│(Alt_0) Makes macfile from txtfile [file].QM               │
  312. *│   Loads macfile [file].MAC.                               │
  313. *└───────────────────────────────────────────────────────────┘
  314. *                   
  315. @0 macrobegin
  316.    savefile dos "qmacbj " currentfilename                    * make file.mac
  317.    backspace backspace backspace return                      *
  318.    unmarkblock begline return cursorup                       * cut name/scrap
  319.    markblockbegin currentfilename markblockend cut           *
  320.    editfile "j:j" return quit                                * quit j:j
  321.    editfile paste return horizontalwindow                    * load file.qm
  322.    editfile "j:j" return                                     * get error file
  323.    insertdate  inserttime                                    * put date in j:j
  324.    find "(" return return jfalse labl1:                      * get error line #
  325.    wordright unmarkblock markblockbegin wordright            *
  326.    cursorleft markblockend copy savefile prevwindow          *
  327.    gotoline paste return makectrofscreen pause zoomwindow    * go to error line
  328.    jump labl2:                                               *
  329.  labl1:                                                      *
  330.    prevwindow zoomwindow                                     * no error, go to
  331.    jump labl2:                                               *      prevwindow
  332.  labl2:                                                      *
  333.    macroread currentfilename backspace backspace "mac" return* read new macro
  334. *
  335. * 98 bytes Thu  07-26-1990  09:08:31
  336.  
  337.  
  338.  
  339. *┌────────────────────────────────────────────────────────────────┐
  340. *│(Alt_t) Selects macfile to read from macfile list sorted by Date│
  341. *└────────────────────────────────────────────────────────────────┘
  342. *
  343. @t macrobegin
  344.         dos "sort-T" return return                           * Sort list/date
  345.         editfile "j:j" return quit editfile "j:j" return     * get file list
  346.         delline delline delline return                       * del dir heading
  347.         "Cursor " #25                                        * instructions
  348.         markblockend begline markblockbegin                  * highlight
  349.         cursordown return                                    * space
  350.         pause markword copy                                  * get macfile name
  351.         editfile paste  ".qm" return quit                    * load text macro
  352.         editfile paste  ".qm" return                         *
  353.         macroread paste ".mac" return                        * read macfile
  354. *
  355. * 94 bytes Thu  07-26-1990  02:14:10
  356.  
  357.  
  358.  
  359.  
  360. *┌─────────────────────────────────────────────────────────────────┐
  361. *│(Alt_n) Selects macfile to read from macfile list sorted by Name │
  362. *└─────────────────────────────────────────────────────────────────┘
  363. *
  364. @n macrobegin
  365.         dos "sort-N" return return                           * Sort list/name
  366.         editfile "j:j" return quit editfile "j:j" return     * get file list
  367.         delline delline delline return                       * del dir heading
  368.         "Cursor "#25                                         * instructions
  369.         markblockend begline markblockbegin                  * highlight
  370.         gotoblockend return return                           * space
  371.         pause markword copy                                  * get macfile name
  372.         editfile paste  ".qm" return quit                    * load text macro
  373.         editfile paste  ".qm" return                         *
  374.         macroread paste ".mac" return                        * read macfile
  375. *
  376. * 95 bytes Thu  07-26-1990  02:14:28
  377.  
  378.  
  379.  
  380. *┌───────────────────────────────────────────────────────────────────┐
  381. *│(Ctl_1) Finds first word on cursor line marked in document below   │
  382. *└───────────────────────────────────────────────────────────────────┘
  383. *
  384. *        Ctl_1 macro has 2 steps:
  385. *
  386. *        1. Press Alt and 1 at the same time. A down arrow shows at the
  387. *        end of the top line. Cursor down to desired line in Index.
  388. *
  389. *        2. Press Enter. The macro first erases the down arrow, and
  390. *        then finds the first word on the cursor line in the document
  391. *        below marked with (...).
  392. *
  393. *        If you load this macro in your QCONFIG.DAT, substitute #25
  394. *        with "" (^P_Y). Remember ^1 requires scan code 02 to
  395. *        convert with QMAC on my system. Your's may be different.
  396. *
  397. 02 macrobegin
  398.         unmarkblock                     * unmark any marked blocks
  399.         begfile endline                 * go to file begin endline
  400.         #25                             * put down arrow at endline
  401.         begline
  402.         find #25 return return begline  * highlight down arrow
  403.         pause                           * pause for Index selection
  404.         wordright markword              * mark first word on line
  405.         copy                            * copy word to scrap buffer
  406.         begfile                         * begfile
  407.         find #25 return return delch    * find & delete down arrow
  408.         endpara                         * go to end of Index
  409.         makectrofscreen                 * cursor line center of window
  410.         find "(" paste ")"
  411.         return "I" return               * find first marked word in doc
  412.  jfalse NOMARK:
  413.         begline                         * if mark found go to begline
  414.  jump END:
  415.  NOMARK:
  416.         begfile                         * if no mark found go to begfile
  417.  END:
  418. *
  419. * 47 bytes Thu  07-26-1990  13:02:27
  420.  
  421.  
  422.  
  423. * (Other) Macros available: See ALLMACRO.INF
  424. *
  425. * (Version) History:
  426. *
  427. * v1.0  -  initial version
  428. * v1.1  -  Changed Alt-6 to keep [file].qm in ring after running.
  429. * v1.2  -  Date & time stamp put in dum.qm (Alt-6, Alt-7).
  430. * v1.3  -  Added batch files to macro13.ZIP.
  431. * v1.4  -  Changed Alt-6 & 7 to stamp [file].QM translated from.
  432. *       -  Changed Alt-0 to not pause if no errors.
  433. *       -  Added Alt-5 to see error file in window.
  434. *       -  Changed /W60 to /W70 and removed "pause" in qmact.bat.
  435. * v1.5  -  Changed Alt-7 to not pause if no errors.
  436. * v1.6  -  Shortened Alt-6, 7 & 10. Faster & no pause now if no errors.
  437. * v1.7  -  Corrected Alt-6 to write macros first. Sorry.
  438. * v1.8  -  Added Alt-4 to append text file [file].qm  macros
  439. *          to a "standard" macro and read appended macro.
  440. * v1.9  -  Added Alt-3 to merge designated macro [file].mac
  441. *          with current macros. QEdit normally overwrites
  442. *          current macros when reading a new macro.
  443. * v2.0  -  Added Alt-2 to refresh macro buffer with "standard" macro.
  444. *       -  New qmacTA2.bat for Alt-4, gets "standard" name as %2.
  445. *       -  Added Alt T & Alt N to select txtfile to read from
  446. *          sorted list of all avaialable txtfiles in directory.
  447. *       -  New SORT-T.BAT and SORT-F.BAT for Alt T & N to sort macro list.
  448. *       -  Changed Alt-4 to identify "standard" rather than batch file.
  449. *          (Modify g:\qe\macros for the name of your "standard" macro.)
  450. *       -  Shortened Alt-3,7 & 0, total 91 bytes. (Important when merging
  451. *          since QEdit macro buffer is limited to 2046 bytes macros.)
  452. *       -  Moved macroread to end of Alt-3. No problem, just in case.
  453. *          (Reading macros while executing can sometimes cause problems.)
  454. *       -  Changed Alt-5 to refresh j:j.
  455. * v2.1  -  (Internal)
  456. * v2.2  -  Added Alt-1 to select txtfile to load from list of all txtfiles
  457. *          in directory sorted by Name. Added sort-N2.bat for this macro.
  458. *       -  Changed Alt T & Alt N to select macfile, not txtfile as v2.0,
  459. *          from sorted list of all available macfiles in directory.
  460. *       -  Changed sort-T.bat, sort-N.bat and sort-N1.bat for macrs.
  461. *       -  Renamed MACCMTxx to MACROxx. Dropped MACCMTxx. Macros comments
  462. *          and instructions are now are in MACROxx.qm.
  463. *       -  Shortened highlight bar in Alt N,t. Saves ~30 bytes/macro.
  464. *       -  Changed dum.dir to $ in Alt-4 & qmacTA2.bat to shorten
  465. *       -  Added killfile to Alt-3 & 4. Changed endfile display in Alt-4.
  466. *       -  Replaced "j:\j" with "j:j" in macros and batch files to shorten.
  467. *       -  Changed qmacTA2.bat for better display.
  468. *       -  Changed select window from "j:j" to "j:$" in batch files
  469. *       -  Sort batch files (sort-xx.bat) also changed.
  470. * v2.3  -  Changed  @5 to keep error file j:j in ring.
  471. *       -  By removing " "'s, changing file name tracking in buffers,
  472. *          and shortening header and footer labels:
  473. *                - shortened @4        28 bytes
  474. *                - shortened @5         5  "
  475. *                - shortened @6        67  "
  476. *                - shortened @7        24  "
  477. *                - shortened @9         3  "
  478. *       -  added macro size 'bytes line' at end of each macro
  479. * v2.4  -  removed dum.qm and dum.mac from zip package
  480. *       -  shortened Alt_6 from 147 to  54 bytes
  481. *       -  shortened Alt_7 from 258 to 194 bytes                              r
  482.  
  483. * error_sample, remove asterisk to test for errors
  484. *
  485. * ...Tom Hogshead  Tue  08-21-1990  19:54:47
  486.